NCLtips! (*'O')v

このNCLtipsのページのロゴは以下のスクリプトで描きました。
少しNCLを勉強した人なら，これを見て何を描いたものかすぐに分かるはず。

load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/contributed.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/shea_util.ncl"

begin

  yyyymm   = 201503
  out      = "eps"
  infile   = "./data/sst.mnmean.nc" ;Monthly OISST V2 from NOAA
  maskfile = "./data/lsmask.nc"     ;data for land-sea mask

  in      = addfile(infile,"r")
  time    = in->time
  YYYYMM  = cd_calendar(time,-1) 
  t1      = ind(YYYYMM.eq.yyyymm)
  sst     = short2flt(in->sst(t1,:,:))
  in_mask = addfile(maskfile,"r")
  lsmask  = short2flt(in_mask->mask(0,:,:))
  sst     = mask(sst,lsmask,1)
  sst     = dim_rmvmean_Wrap(sst)

  wks = gsn_open_wks(out,"figure")
  res                             = True
  res@gsnFrame                    = False
  res@gsnDraw                     = False
  res@cnFillOn                    = True
  res@cnLinesOn                   = False
  res@cnLineLabelsOn              = False
  res@cnInfoLabelOn               = False
  res@lbLabelBarOn                = False
  res@mpProjection                = "Satellite"
  res@mpCenterLonF                = 145
  res@mpCenterLatF                =  15
  res@mpDataBaseVersion           = "MediumRes"
  res@mpGeophysicalLineThicknessF = 0
  res@mpLandFillColor             = "burlywood3"
  res@mpPerimOn                   = False
  res@cnFillPalette               = "NCV_jet"
  res@cnFillDrawOrder             = "PreDraw"
  res@cnMissingValFillColor       = res@mpLandFillColor
  res@cnLevelSelectionMode        = "ManualLevels"
  res@cnMinLevelValF              = -6.
  res@cnMaxLevelValF              =  6.
  res@cnLevelSpacingF             =   .05
  res@gsnLeftString               = ""
  res@gsnRightString              = ""
  plot = gsn_csm_contour_map(wks,sst,res)
  draw(plot)
  frame(wks)

end